Envio de notificaciones desde NodeMcu con Pushbullet

Este es un tema que ya había tratado previamente cuando estábamos trabajando con MicroPython, pero en esta ocasión quiero abordar el tema si estamos trabajando directamente con el IDE de Arduino.

Veremos como enviar mensajes simples desde NodeMCU a un telefono por medio de la API de PushBullet.

En primer lugar comenzaremos instalando la aplicacion Pushbullet en el teléfono, luego que se encuentre instalada y se cree una cuenta, debemos obtener el API Key para poder conectarnos a los servidores de Pushbullet:

Primero vamos a Setting, y luego hacemos clic en el botón «Create Access Token», nos va a mostrar una caja de texto con una cadena de caracteres que será nuestro token para poder conectarnos.

Cada vez que ingresemos en esa pantalla Pushbullet crea un nuevo Token y se descarta el anterior, por lo que es conveniente copiarlo en un bloc de notas. No compartan el token.

Construiremos un sencillo circuito para enviar mensajes cada vez que presionamos un botón:

El botón tiene conectado un pin a GND y el otro a D2.

Respecto al código del ejemplo, simplemente debemos realizar una petición a la API de Pushbullet de la siguiente manera:

const char* host = "api.pushbullet.com"; 
const char* apiKey = "TOKEN";
void enviarMensaje(String titulo,String mensaje) {
  
  WiFiClientSecure client;
  client.setInsecure();
  if(!client.connect(host,443)) {
    Serial.println("No se pudo conectar con el servidor");
    return;
  }

String url = "/v2/pushes";
  String message = "{\"type\": \"note\", \"title\": \""+titulo+"\", \"body\": \""+mensaje+"\"}\r\n";
  Serial.print("requesting URL: ");
  Serial.println(url);
  //send a simple note
  client.print(String("POST ") + url + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Authorization: Bearer " + apiKey + "\r\n" +
               "Content-Type: application/json\r\n" +
               "Content-Length: " +
               String(message.length()) + "\r\n\r\n");
  client.print(message);

  delay(2000);
  while (client.available() == 0);

  while (client.available()) {
    String line = client.readStringUntil('\n');
    Serial.println(line);
  }  
}

Luego desde loop() invocamos a la función definida de la siguiente manera:

void loop() {

  if(digitalRead(pinBoton) == LOW) {
    Serial.println("Presionado");

    enviarMensaje("NodeMCU","Mensaje enviado desde NodeMCU");
    delay(2000);
    
  }

  delay(100);
}

Cada vez que presionemos el botón, el dispositivo enviara un mensaje. Es recomendable implementar algún mecanismo/procedimiento para que no se envíen múltiples mensajes al mismo tiempo; para el ejemplo simplemente hice esperar al dispositivo por 2 segundos.

Aquí pueden encontrar el ejemplo del código.

ESP8266 y Google SpreadSheets

En artículos anteriores abordamos el tema de guardar datos de los sensores en Excel, sea por medio de un script en Python que recibe los datos por medio de MQTT o mediante el puerto serie; en esta ocasión quiero trabajar con las planillas de calculo de Google, puesto que ofrecen la posibilidad de escribir scripts para automatizar tareas.

Serán estos scripts los que nos ayudaran a guardar la información de los sensores conectados al microcontrolador (para el ejemplo utilizare un ESP8266, pero puede ser cualquiera) en una planilla.

Utilizaremos un sensor de gases MQ-5 para el ejemplo, pero es posible utilizar cualquier sensor disponible; el objetivo es registrar en la planilla la fecha y hora de la medición y el valor de la lectura.

Comenzaremos ingresando en Google Drive y creando una Hoja de Cálculo nueva, la llamaremos nivelGas y en la columna A indicaremos como titulo Fecha y Hora; en la columna B Nivel Gas a modo informativo.

Luego que se haya guardado la planilla, debemos crear el script que realizara los cambios sobre la misma; para ello vamos al menú Herramientas – Editor de secuencias de comandos:

Se abrirá una nueva ventana en nuestro navegado que contiene un editor para que podamos cargar el código que utilizaremos:

Aquí debemos indicar el nombre del proyecto, en mi caso utilizare modificarHoja y debemos copiar el siguiente código:

function doPost(e) {
   var ss1 = SpreadsheetApp.getActiveSpreadsheet();
   var sheet = ss1.getSheets()[0];

   var fechaHora = Utilities.formatDate(new Date(), "GMT-3", "yyyy-MM-dd HH:mm:ss");
   valor = String(e.parameters.data);
   sheet.appendRow([fechaHora,valor]);
   
   return ContentService.createTextOutput("Completo");
}

Este sencillo programa toma la hoja de cálculos abierta y de la misma identifica la primer hoja y por ultimo agrega una fila con los datos que fueron enviados desde el NodeMCU.

Por ultimo debemos establecer los permisos y accesos sobre el script para poder ejecutar correctamente, debemos ir a Publicar – Implementar como aplicación web

Debemos elegir que se ejecute como nuestro usuario y que cualquier persona incluso los anónimos tengan acceso a la aplicación; luego confirmamos las opciones que se nos presenta.

Copiamos la url que nos presenta, la utilizaremos en el programa del ESP8266.

Construiremos un sencillo circuito para tomar datos del entorno y guardarlos en la hoja de calculo, utilizaremos un sensor de gas MQ-5 que va conectado:

NodeMCUMQ-5
3v3VCC
GNDGND
A0A0

En el Arduino IDE utilizaremos las librerías y variables siguientes:

#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>

const char* ssid = "SSID"; //Replace with your own
const char* password = "PASSWORD";

const char* myDomain = "script.google.com";

String script = "/macros/s/XXXXXXXXXXXXXXXXXXXXX/exec";

long ultimoReporte=0;
long periodoReportes = 60 * 1000; 

Donde ssid y password reemplazamos por los valores correspondientes a nuestra red wifi y en el variable script reemplazamos XXXXXXXXXXXXXXXXXXXXX por la correspondiente que nos otorgo Google Script.

Luego el metodo setup() es sencillo solo establecemos la salida serie y la conexion a la red. En el metodo loop tendremos lo siguiente:

void loop() {
  
  if ((millis() - ultimoReporte) > periodoReportes) {
    
    if(WiFi.status() != WL_CONNECTED) {
      setup_wifi();
    }
    ultimoReporte = millis();
    int valor = analogRead(0);
    Serial.println(valor);
    enviarDatosCloud(valor);
  }

}

Respecto a la función enviarDatosCloud(), es la que se conecta al script de Google y pasa los parametros determinados:

void enviarDatosCloud(int valor) {
  WiFiClientSecure clientSecure;
  if (clientSecure.connect(myDomain, 443)) {
    Serial.println("Connection successful");  

    String Data = "data="+String(valor);
    clientSecure.println("POST " + script + " HTTP/1.1");
    clientSecure.println("Host: " + String(myDomain));
    clientSecure.println("Content-Length: " + String(Data.length()));
    clientSecure.println("Content-Type: application/x-www-form-urlencoded");
    clientSecure.println();
    
    clientSecure.print(Data);    
    Serial.println("Waiting for response.");
    long int StartTime=millis();
    while (!clientSecure.available()) {
      Serial.print(".");
      delay(100);
      if ((StartTime+60000) < millis()) {
        Serial.println();
        Serial.println("No response.");
        break;
      }
    }
    Serial.println(); 
    
    while (clientSecure.available()) {
      Serial.print(char(clientSecure.read()));
    }  
    
  } else {
    Serial.println("Connected to " + String(myDomain) + " failed.");
  }
  clientSecure.stop();
}

Si todo esta correcto deberíamos poder compilar y al cabo de 60 segundos se actualizara nuestra hoja de cálculo; podemos cambiar el tiempo de actualización cambiando el valor de la variable periodoReportes.

En breve publicare en github el repositorio con el código del ejemplo.